求：GHOST后批处理修改机器名，IP地址！！！！！！！

2025-04-04 03:32:27

推荐回答（4个）

回答1：

@echo off

:::--------------------------------------------------------------------------
:::::请你在使用把[MacAddress] 字段下改为你自己的机器配置：：：：：：：：：
:::::此文件，只在win2k 专业版下测试过：：：：：：：：：：：：：
:::::带有“::::” 后面的语句为注释：：：：：：：：：：
:::::因为会修改你的机器配置。请在测试机器上使用！：：：：：
:::---------------------------------------------------------------------

@cls :::清屏
@echo [ComputerName] [MacAddress] [IPAddress] [CS-CDKey] >config.cfg
@echo Nh005 00-11-5B-CF-C8-12 192.168.0.5 3245164654063 >>config.cfg
@echo Nh006 00-11-5B-BD-2F-E4 192.168.0.6 3385636230783 >>config.cfg
@echo Nh007 00-11-5B-B3-F0-86 192.168.0.7 2030698167302 >>config.cfg
@echo Nh008 00-11-5B-C8-C8-E1 192.168.0.8 7149496192146 >>config.cfg
:::::::添加你自己的机器配置
::::获取机器的TCP/IP 配置
if exist ipconfig.txt del ipconfig.txt
ipconfig /all >ipconfig.txt

:::分离出机器的物理地址，并保存到 ( phyaddr.txt) 文件中
if exist phyaddr.txt del phyaddr.txt
find "Physical Address" ipconfig.txt >phyaddr.txt

::::从(c:\phyaddr.txt)文件中取得物理地址字符串，并赋给变量"MacAddress"
for /f "skip=2 tokens=12" %%M in (phyaddr.txt) do set strMac=%%M

:::显示物理地址字符串
@echo %strMac%

::::以变量"strMac"为关键字搜索(Config.cfg)中相同的字符串行，并保存到(ComputerCfg.txt)
find "%strMac%" Config.cfg >ComputerCfg.txt

::::显示机器名. (从"ComputerCfg.txt"中分离出机器名字段，并赋给变量"ComputerName")
for /f "skip=2 tokens=1" %%N in (ComputerCfg.txt) do set ComputerName=%%N
@echo %ComputerName%

::::显示IP地址. (从"ComputerCfg.txt"中分离出 IP地址字段，并赋给变量"IPAddress")
for /f "skip=2 tokens=3" %%I in (ComputerCfg.txt) do set IPAddress=%%I
@echo %IPAddress%

::::显示网卡MAC地址.(从"ComputerCfg.txt"中分离出 MAC地址字段，并赋给变量"MacAddress")
for /f "skip=2 tokens=2" %%M in (ComputerCfg.txt) do set MacAddress=%%M
@echo %MacAddress%
for /f "skip=2 tokens=4" %%C in (ComputerCfg.txt) do set strCdkey=%%C
@echo %strCdkey%
::::创建注册表文件
@echo Windows Registry Editor Version 5.00 >ComputerName.reg
@echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName] >>ComputerName.reg

::::用变量"%ComputerName%"去替换实际的机器名
@echo "ComputerName"="%ComputerName%" >>ComputerName.reg
@echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters] >>ComputerName.reg

::::用变量"%ComputerName%"去替换实际的机器名
@echo "NV Hostname"="%ComputerName%" >>ComputerName.reg
@echo "Hostname"="%ComputerName%" >>ComputerName.reg
::::修改 CS-CDKEY 不用管它
@echo [HKEY_CURRENT_USER\Software\Valve\CounterStrike\Settings]>>ComputerName.reg
@echo "Key"="%strCdkey%">>ComputerName.reg
@echo [HKEY_USERS\S-1-5-21-839522115-507921405-2146800195-500\Software\Valve\CounterStrike\Settings]>>ComputerName.reg
@echo "Key"="%strCdkey%">>ComputerName.reg

::::导入注册表文件。用的时候把" :: " 去掉
regedit /s ComputerName.reg

::::修改IP 地址。用变量"%IPAddress%" 去替换实际的IP 地址
netsh interface ip set address name="本地连接" source=static addr=%IPAddress% mask=255.255.255.0 gateway=192.168.0.1 gwmetric=1
::::重起机器批处理！
setlocal
cd/d %temp%
echo [version] > reboot.inf
set inf=InstallHinfSection DefaultInstall
echo signature=$chicago$ >> reboot.inf
echo [defaultinstall] >> reboot.inf
rundll32 setupapi,%inf% 1 %temp%\reboot.inf
del reboot.inf

c:
cdcd %USERPROFILE%\「开始」菜单\程序\启动
del /q *.*

回答2：

我以前在网吧是这样做的：

在把系统封装成GHOST之前，在桌面放一个设置IP地址的小工具，系统的IP地址和DNS设置都留空，然后进行GHOST备份。

然后网络GHOST恢复到所有客户机，恢复完毕自动重新启动进入系统。
然后每台机第一次开机的时候就打开桌面的设置IP的工具填入这台机D位IP就可以了，因为这个工具自动设置前三位和网关、子掩码和DNS。

没有办法做得到自动设置不同IP，只能做到更省力一点而已。

补充回答：暂时没有试过，也没有听说过。MAC地址里面没有记忆IP地址的功能啊！
只能利用软件方便一点了，以前我做600台客户机也是这样。

回答3：

已经有以前的IP地址与MAC地址？？
？？？？？？？？？？？？？？？？

什么意思啊？

MAC地址看看是不是本机的MAC地址
cmd ipconfig/all

回答4：

更改电脑名:
@echo off
color F2
set /p name=请输您的计算机名：
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v ComputerName /t reg_sz /d %name% /f
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f
cls
echo

设置IP:
@echo off
set slection1=
set/p slection1=请输入IP地址：
netsh interface ip set address name="本地连接" source=static addr=%slection1% mask=255.255.255.0
set slection2=
set/p slection2=请输入网关地址：
netsh interface ip set address name="本地连接" gateway=%slection2% gwmetric=0

set slection3=
set/p slection3=请输入主dns地址
netsh interface ip set dns name="本地连接" source=static addr=%slection3% register=PRIMARY

set slection4=
set/p slection4=请输入备份dns地址
netsh interface ip add dns name="本地连接" addr=%slection4%
netsh interface ip set wins name="本地连接" source=static addr=none
pause

最新问答

农民工工拖欠劳动局能解决吗

爱和犯贱有什么区别（男女感情上）？？？

衡阳到北京自驾高速多少公里,收费多少,多少时间

只有炎龙侠地虎侠风鹰侠3个铠甲勇士的是什么?

母狗也会来月经吗？什么颜色的？

金融资产管理公司需要什么条件可以开？

大连哪里有回收钻石戒指的？需要什么手续？价格是怎么算的？

中国板材十大名牌排行榜（2016）

江门车站有咩车到台山港海？票价是多少？台山最后一班车到江门是几点？

请问一下上海电信手机卡性价比怎么样？