用汇编语言怎么让1602输出ABC三个字母，(只要在屏幕上就好，写个完整程序给我，要备注，记得用汇

;1602显示ABC

LCD_RS EQU P2.0
LCD_RW EQU P2.1
LCD_EN EQU P2.2
LCD_DATA EQU P0

;-----------------
ORG 0000H
JMP START
ORG 0030H
;-----------------
START:
CALL LCD_INIT
MOV A, #80H
CALL LCD_WCMD
MOV A, #'A'
CALL LCD_WDATA
MOV A, #'B'
CALL LCD_WDATA
MOV A, #'C'
CALL LCD_WDATA
AJMP $
;----------------
DELAY5MS:
MOV R6, #10
DL1:DJNZ R7, $
DJNZ R6, DL1
RET
;----------------
LCD_INIT:
CALL DELAY5MS
MOV A, #38H
CALL LCD_WCMD
CALL DELAY5MS
CALL DELAY5MS
MOV A, #06H
CALL LCD_WCMD
MOV A, #01H
CALL LCD_WCMD
MOV A, #0CH
CALL LCD_WCMD
RET
;=====================================
LCD_WCMD:
CALL CHECKBUSY
CLR LCD_RS
JMP W_LCD
;----------------
LCD_WDATA:
CALL CHECKBUSY
SETB LCD_RS
W_LCD:
CLR LCD_RW
MOV LCD_DATA, A
SETB LCD_EN
NOP
CLR LCD_EN
RET
;----------------
CHECKBUSY:
PUSH ACC
MOV LCD_DATA, #255
CLR LCD_RS
SETB LCD_RW
BUSYLOOP:
SETB LCD_EN
NOP
MOV A, LCD_DATA
CLR LCD_EN
JB ACC.7, BUSYLOOP
POP ACC
RET
;=====================================
END

程序已经仿真成功。

用dos二号功能调用逐个输出就可以了

什么系统啊？ 51还是 arduino?